Éléments de corrigé

Rappel des trois objectifs poursuivis

- Évaluer les débits instantané et moyen de la pompe étudiée, la motopompe RV2.
- Évaluer l'influence du réglage sur le débit moyen précédent.
- Généralisation : étude de l'influence du nombre de pistons.

Stratégie et notations adoptées

En vue d'atteindre ces objectifs, on va définir successivement les expressions et fonctions débit volume sortant suivantes :

	débit instantané du piston modélisé, baptisé piston n°1
	débit moyen de ce piston
	débit instantané du piston n°k d'une pompe à n pistons
	débit instantané d'une pompe à n pistons
	débit moyen d'une pompe à n pistons

Initialisation

Chargement des bibliothèques utiles

restart:
with(plots):

Définition des constantes

Les constantes suivantes permettent une lecture aisée des unités et convertissent les unités données dans le système international.
Par exemple, on tape θ = 20*deg pour avoir la valeur de l'angle en radian.

deg := Pi/180:  #degré
tr  := 2*Pi:    #tour
mn  := 60:      #minute
mm  := 10^(-3): #millimètre
l   := 10^(-3): #litre

Expression de la vitesse et données numériques

La loi d'entrée-sortie trouvée lors de l'étude préliminaire, pour un réglage θ donné, est la suivante :

La fréquence de rotation du moteur est supposée constante. Soit = cste. Et on pose
La fonction avec laquelle on va travailler est ainsi

La vitesse instantanée d'un piston par rapport au barillet est une fonction périodique, la période [2π] correspondant à un tour de barillet par rapport au bâti

v:=R*omega*tan(theta)*sin(alpha);

Données géométriques et cinématiques pour le groupe hydraulique V2H40

R : rayon d'implantation des pistons dans le barillet
ω : vitesse de rotation du barillet par rapport au bâti
d : diamètre d'un piston
tm : valeur de θ_max

val:=[

 R     = 9.5*mm,
 omega = 2000*tr/mn,
 d     = 6*mm,
 tm    = 20*deg

];

Visualisation pour θ = 20° :

c_vit:=plot
(
   subs(theta=tm,val,v)
  ,alpha=0..360*deg
  ,thickness=2
):

d_verte:=plot
(
   [[Pi,-.8],[Pi,.8]]
  ,color=green
):

display({c_vit,d_verte}
  ,title=`Vitesse [m/s] du piston par rapport au barillet`
  ,TEXT([4.7,.2],'Aspiration',FONT(COURIER,12))
  ,TEXT([1.7,.2],'Refoulement',FONT(COURIER,12))
  ,TEXT([4.7,-.8],`www.jdotec.net`,FONT(COURIER,6))
);

Débits volumes sortants de la pompe RV2

Débits instantané et moyen du piston n°1

Le débit instantané sortant de la pompe est obtenu lors de la phase de refoulement, et est obtenu par exemple par la fonction max() :

Avec Maple, cette fonction pose des soucis lors des calculs l'intégration à venir, et on prend alors comme fonction équivalente :

Le débit moyen est obtenu en intégrant le débit instantané sur une période.
Les débits sont convertis ici en l/mn, qui est l'unité fournie par le débitmètre du banc de puissance.

qv1 := 1/2*(v+abs(v))*Pi*d^2/4/(l/mn);
qv1m:= int(qv1,alpha=0..360*deg)/(2*Pi);

Visualisation des débits instantané et moyen pour 1 piston et pour θ = θ_max

qv1m_20:=evalf(subs(theta=tm,val,qv1m));
 
c_qv1  :=plot
(
   subs(theta=tm,val,qv1)
  ,alpha=0..360*deg
):
 
c_qv1m :=plot
(
   [[0,qv1m_20],[2*Pi,qv1m_20]]
  ,color=green
):

c_qv1m_20:=cat(substring(convert(qv1m_20,string), 1..3) ,` l/mn`):

display({c_qv1,c_qv1m}
  ,thickness=2
  ,title=`Débits [l/mn]`
  ,TEXT([4.5,.45],'Moyen',FONT(COURIER,12))
  ,TEXT([4.5,.33],`c_qv1m_20`,FONT(COURIER,10))
  ,TEXT([3.5,.9],`Instantané`,FONT(COURIER,12))
);

Visualisation du débit instantané pour 1 piston et pour θ variant de 0 à 20°.

#plot3d(subs(val,qv1),alpha=0..360*deg,theta=0..20*deg);

Débit sortant du piston n° k pour une pompe à n pistons :

L'angle α caractérise la rotation du barillet par rapport au bâti. Le premier piston a été supposé en phase avec le barillet. Les autres pistons sont déphasés d'un multiple du pas angulaire

Substituons alors dans l'expression de qv1 à la variable la variable

qvk:=(k,n)->subs(alpha=alpha+2*(k-1)*Pi/n,qv1);

Visualisation des débits instantanés pour la pompe RV2 qui comporte 6 pistons

c_qvk:=plot
(
   {seq(subs(theta=tm,val,qvk(k,6)),k=1..6)}
  ,alpha=0..360*deg
  ,color=gray
):
 
c_qv5:=plot
(
   subs(theta=tm,val,qvk(5,6))
  ,alpha=0..360*deg
  ,thickness=2
  ,color=aquamarine
):

display({c_qvk,c_qv5}
  ,title=`Débit issu du piston k/6 [l/mn]`
  ,TEXT([4.75,1.1],`k=4`,FONT(COURIER,12))
  ,TEXT([3.65,1.1],`k=5`,FONT(COURIER,12))
  ,TEXT([2.60,1.1],`k=6`,FONT(COURIER,12))
  ,TEXT([1.55,1.1],`k=1`,FONT(COURIER,12))
  ,TEXT([0.50,1.1],`k=2`,FONT(COURIER,12))
  ,TEXT([5.75,1.1],`k=3`,FONT(COURIER,12))
);

Expression des débits instantané et moyen d'une pompe à n pistons

Le débit instantané qvn est obtenu en sommant les débits partiels qvk issus des différents pistons :

qvn :=n->sum(qvk(k,n),k=1..n);
qvnm:=n->int(qvn(n),alpha=0..360*deg)/(2*Pi);

Visualisation des débits instantané et moyen pour la pompe RV2.

qv6m_20:=evalf(subs(theta=tm,val,qvnm(6)));
c_qv6 :=plot
(
   subs(theta=tm,val,qvn(6))
  ,alpha=0..360*deg
  ,y=0..3
):
 
c_qv6m:=plot
(
   [[0,qv6m_20],[2*Pi,qv6m_20]]
  ,color=green
):
 
display({c_qv6,c_qv6m}
  ,thickness=2
  ,title=`Débits volumes [l/mn]`
  ,TEXT([3.14,1.8],`Moyen en vert`,FONT(COURIER,12))
  ,TEXT([3.14,2],`Instantané en rouge`,FONT(COURIER,12))
);

Influence du nombre de pistons

Pour cette partie, on fixe le réglage du débit à θ_max = 20°.
On souhaite étudier l'évolution des débits instantané et moyen en fonction du nombre n de pistons.
On reprend pour cela les deux fonctions qvn(n) et qvnm(n) et on fait varier n de 1 à 7

Courbes de débit instantané :

c_1:=plot
(
   {seq(subs(theta=tm,val,qvn(n)),n=2..7)}
  ,alpha=0..360*deg
  ,color=red
):

Liste des valeurs des débits moyens :

t_qvm:=[seq(subs(theta=tm,val,qvnm(n)),n=1..7)]:
evalf(t_qvm);
c_2:=plot
(
   {seq([[0,t_qvm[n]],[2*Pi,t_qvm[n]]],n=1..7)}
  ,color=green
):

display({c_1,c_2}
  ,title=`Débits en fonction de n [l/mn]`
  ,TEXT([4.75,.50],`n=1`,FONT(COURIER,12))
  ,TEXT([4.75,.90],`n=2`,FONT(COURIER,12))
  ,TEXT([4.20,1.30],`n=3`,FONT(COURIER,12))
  ,TEXT([4.75,1.70],`n=4`,FONT(COURIER,12))
  ,TEXT([4.75,2.10],`n=5`,FONT(COURIER,12))
  ,TEXT([4.75,2.55],`n=6`,FONT(COURIER,12))
  ,TEXT([4.75,2.85],`n=7`,FONT(COURIER,12))
);

Conclusion :

On constate une différence de comportement entre les nombres pairs et impairs de pistons :
Le débit instantané est périodique de période lorsque n est pair, de période lorsque n est impair.
En conséquence, le débit instantané est plus régulier lorsque l'on a un nombre impair de pistons.

Quantification de l'irrégularité du débit

Une première étape consiste à déterminer les valeurs mini et maxi des débits instantanés.
Ceci est fait pour n variant de 2 à 7 :

for i from 2 to 7
do
  int_max[i]:=evalf(`if`(i mod(2)> 0,1,2)*Pi/(i+1));
  qv_maxi[i]:=maximize(subs(theta=tm,val,qvn(i)),alpha,{alpha=0..int_max[i]});
  qv_mini[i]:=minimize(subs(theta=tm,val,qvn(i)),alpha,{alpha=0..int_max[i]});
  pourcent[i]:=evalf(100*(t_qvm[i]-qv_mini[i])/t_qvm[i]);
od:;

Visualisation

d_lin:=plot([[0,0],[7,t_qvm[7]]],color=blue):

c_var_qv:=plot
(
   {seq([[n,qv_mini[n]],[n,qv_maxi[n]]],n=2..7)}
  ,thickness=2
  ,color=green
):
 
c_qv_moy:=plot
(
   {seq([[n,t_qvm[n]]],n=2..7)}
  ,style=point
  ,symbol=circle
  ,color=red
):
 
d_leg:=plot
(
   [[1,2.4],[1,2.6]]
  ,thickness=2
  ,color=green
):
 
p_leg:=plot
(
   [[1,2.2]]
  ,color=red
  ,style=point
  ,symbol=circle
):

display({d_lin,c_var_qv,c_qv_moy,d_leg,p_leg}
  ,title=`Irrégularité du débit (n de 2 à 7)`
  ,TEXT([1.2,2.5],`Amplitude`,ALIGNRIGHT,FONT(COURIER,12))
  ,TEXT([1.2,2.2],`valeur moyenne`,ALIGNRIGHT,FONT(COURIER,12))
  ,TEXT([7,.2] ,`n` ,FONT(COURIER,14))
  ,TEXT([2.1,.2] ,`100%`,FONT(COURIER,10))
  ,TEXT([3.1,.9] ,`9,3%`,FONT(COURIER,10))
  ,TEXT([4.1,1.1],`21%` ,FONT(COURIER,10))
  ,TEXT([5.1,1.7],`3,3%`,FONT(COURIER,10))
  ,TEXT([6.1,2] ,`9,3%`,FONT(COURIER,10))
  ,TEXT([7.1,2.5],`1,7%`,FONT(COURIER,10))
);